/****************************************************************************
**
** Copyright (C) 2017 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of the examples of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:BSD$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** BSD License Usage
** Alternatively, you may use this file under the terms of the BSD license
** as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
** * Redistributions of source code must retain the above copyright
** notice, this list of conditions and the following disclaimer.
** * Redistributions in binary form must reproduce the above copyright
** notice, this list of conditions and the following disclaimer in
** the documentation and/or other materials provided with the
** distribution.
** * Neither the name of The Qt Company Ltd nor the names of its
** contributors may be used to endorse or promote products derived
** from this software without specific prior written permission.
**
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
**
** $QT_END_LICENSE$
**
****************************************************************************/
// root object
// May I just say in passing that QML is horrible syntactically?
// (Well designed, but still horrible.)
import QtQuick
import QtMultimedia
Rectangle {
id : cameraUI
signal imageCaptured(variant previewImage)
signal previewSaved
signal fileNoLongerNeeded(string filename) // RNC
width: 800
height: 480
color: "black"
state: "PhotoCapture"
property string platformScreen: ""
property int buttonsPanelLandscapeWidth: 328
property int buttonsPanelPortraitHeight: 180
onWidthChanged: {
setState()
}
function setState() {
if (Qt.platform.os === "android" || Qt.platform.os === "ios") {
if (Screen.desktopAvailableWidth < Screen.desktopAvailableHeight) {
stillControls.state = "MobilePortrait";
} else {
stillControls.state = "MobileLandscape";
}
} else {
stillControls.state = "Other";
}
console.log("State: " + stillControls.state);
stillControls.buttonsWidth = (stillControls.state === "MobilePortrait")
? Screen.desktopAvailableWidth/3.4 : 144
}
states: [
State {
name: "PhotoCapture"
StateChangeScript {
script: {
camera.start()
}
}
},
State {
name: "PhotoPreview"
},
State {
name: "VideoCapture"
StateChangeScript {
script: {
camera.start()
}
}
},
State {
name: "VideoPreview"
StateChangeScript {
script: {
camera.stop()
}
}
}
]
CaptureSession {
id: captureSession
camera: Camera {
id: camera
onErrorOccurred: function(error, errorString) {
console.log("camera: onErrorOccurred")
console.log(error)
console.log(errorString)
}
}
imageCapture: ImageCapture {
id: imageCapture
onErrorOccurred: function(requestId, error, message) {
console.log("imageCapture: onErrorOccurred")
console.log(error)
console.log(message)
}
onImageCaptured: function(requestId, previewImage) {
console.log("Image captured")
stillControls.previewAvailable = true
cameraUI.state = "PhotoPreview"
cameraUI.imageCaptured(previewImage)
}
onImageSaved: function(requestId, path) {
console.log("onImageSaved: ", path)
stillControls.fileSaved = true
stillControls.filePath = path
}
}
recorder: MediaRecorder {
id: recorder
}
videoOutput: viewfinder
}
PhotoPreview {
id : photoPreview
anchors.fill : parent
onClosed: cameraUI.state = "PhotoCapture"
visible: (cameraUI.state === "PhotoPreview")
focus: visible
onPreviewSaved: {
cameraUI.previewSaved()
cameraUI.fileNoLongerNeeded(stillControls.filePath)
}
}
VideoPreview {
id: videoPreview
anchors.fill: parent
onClosed: cameraUI.state = "VideoCapture"
visible: (cameraUI.state === "VideoPreview")
focus: visible
//don't load recorded video if preview is invisible
source: visible ? recorder.actualLocation : ""
}
VideoOutput {
id: viewfinder
visible: ((cameraUI.state === "PhotoCapture") || (cameraUI.state === "VideoCapture"))
x: 0
y: 0
width: ((stillControls.state === "MobilePortrait") ? parent.width : (parent.width-buttonsPanelLandscapeWidth))
height: ((stillControls.state === "MobilePortrait") ? parent.height - buttonsPanelPortraitHeight : parent.height)
}
PhotoCaptureControls { // See PhotoCaptureControls.qml
id: stillControls
state: setState()
anchors.fill: parent
buttonsPanelPortraitHeight: cameraUI.buttonsPanelPortraitHeight
buttonsPanelWidth: cameraUI.buttonsPanelLandscapeWidth
captureSession: captureSession
visible: (cameraUI.state === "PhotoCapture")
onPreviewSelected: cameraUI.state = "PhotoPreview"
onVideoModeSelected: cameraUI.state = "VideoCapture"
previewAvailable: imageCapture.preview.length !== 0
// RNC:
onFileNoLongerNeeded: {
cameraUI.fileNoLongerNeeded(stillControls.filePath)
}
}
VideoCaptureControls {
id: videoControls
state: stillControls.state
anchors.fill: parent
buttonsWidth: stillControls.buttonsWidth
buttonsPanelPortraitHeight: cameraUI.buttonsPanelPortraitHeight
buttonsPanelWidth: cameraUI.buttonsPanelLandscapeWidth
captureSession: captureSession
visible: (cameraUI.state === "VideoCapture")
onPreviewSelected: cameraUI.state = "VideoPreview"
onPhotoModeSelected: cameraUI.state = "PhotoCapture"
}
}